Programación en BASIC

[vreyes1981]

Buenos tardes. Escribo aquí estas líneas porque he descubierto los antiguos cargadores que se incluían en Micromania de la 2ª época que se escribían en BASIC para obtener trucos o ventajas en los juegos. En este caso en versión PC. El problema es que al crear el archivo en BASIC, cuando lo compilo bajo el comando RUN, me sale el siguiente error:

Error en la línea data 5

Break in 170

Adjunto en spoiler el código en BASIC. Aviso que es un buen tocho:

Spoiler (click para mostrar/ocultar)

10 REM -----------------------------------------
20 REM Cargador Gryzor por Victor Reyes Morales
30 REM -----------------------------------------
40 REM
50 N$ = "CGRYZ": NB = 220: NL = NB / 20: DIM BYTE(NB): A=10: B=11: C=12: D=13: E=14: F=15
60 COLOR 6, 0, 0: CLS
70 LOCATE 13, 36: PRINT "ESPERE..."
80 CP = 0
90 FOR W1 = 1 TO NL
100 CHECKSUM = 0: Z = 1: READ L$, SUMA
110 FOR W2 = 1 TO 39 STEP 2
120 B1$ = MID$ (L$,Z,1): B2$ = MID$ (L$,Z+1,1): Z = Z + 2
130 A1 = ASC(B1$): A2 = ASC(B2$)
140 NIB1 = A1+48*(A1<58)+55*(A1>57): NIB2 = A2+48*(A2<58)+55*(A2>57)
150 BYTE(CP) = NIB1 * 16 + NIB2: CHECKSUM = CHECKSUM + BYTE(CP): CP = CP + 1
160 NEXT W2
170 IF CHECKSUM <> SUMA THEN CLS: LOCATE 12, 29: PRINT "ERROR EN LINEA DATA "; W1: LOCATE 22, 1: STOP
180 NEXT W1
190 LIN = 9: K = 255
200 CLS
210 LOCATE  1, 31: COLOR 7: PRINT "Cargador GRYZOR"
220 LOCATE  3, 23: COLOR 2: PRINT "(C) Victor Reyes Morales 2023": COLOR 6
230 LOCATE  9, 20: PRINT "Activar vidas infinitas Jugador 1 (s/n)?...... s"
240 LOCATE 11, 20: PRINT "Activar vidas infinitas Jugador 2 (s/n)?...... s"
250 LOCATE 13, 20: PRINT "Activar Tiempo Infinito (s/n)?................ s"
260 LOCATE 15, 20: PRINT "Activar Inmunidad ambos jugadores (s/n)?...... s"
270 LOCATE 17, 20: PRINT "Activar modo sin enemigos (s/n)?.............. s"
280 LOCATE 19, 20: PRINT "Unidad para salvar el cargador................. b"
290 GOSUB 490
300 IF X$ = "N" OR X$ = "n" THEN BYTE(54) = K: Y$ = X$
310 GOSUB 510: GOSUB 490
320 IF X$ = "N" OR X$ = "n" THEN BYTE(60) = K: Y$ = X$
330 GOSUB 510: GOSUB 490
340 IF X$ = "N" OR X$ = "n" THEN BYTE(66) = K: Y$ = X$
350 GOSUB 510: GOSUB 490
360 IF X$ = "N" OR X$ = "n" THEN BYTE(71) = K: Y$ = X$
370 GOSUB 510: GOSUB 490
380 IF X$ = "N" OR X$ = "n" THEN BYTE(76) = K: Y$ = X$
390 GOSUB 510: GOSUB 490
400 IF X$ = CHR$ (13) THEN X$ = "b"
410 Y$ = X$: U$ = X$: GOSUB 510
420 LOCATE 22, 26: COLOR 0,3: PRINT " Pulsa <INTRO> si es correcto ": COLOR 6, 0: X$ = INPUT$(1): IF X$ <> CHR$(13) THEN RUN
430 FOR F = 0 TO NB-1: COD$ = COD$ + CHR$ (BYTE(F)): NEXT
440 OPEN "O", #1, U$+":"+N$+".COM", NB
450 PRINT #1, COD$
460 CLOSE
470 CLS
480 SYSTEM
490 Y$ = "s": LOCATE LIN, 65: COLOR 4: PRINT CHR$(17): COLOR 6: X$ = INPUT$(1)
500 RETURN
510 LOCATE LIN, 63: PRINT Y$;"  ": LIN = LIN + 2
520 RETURN
530 REM
540 DATA "0E588ED88EC0B4098D168F01CD21B408CD218D16", 2117
550 DATA "6901C70677016529C706790165298D1E7701B44B", 1588
560 DATA "B003CD21722FB855298ED8C70639439090C7066B", 2175
570 DATA "449090C6060004C3C606F632EBC606E642C38EC0", 2523
580 DATA "B8005EBED0BC8000EA1000A22F0E1F8D167B01B4", 1915
590 DATA "09CD21CD20613A5C6772797A6F722E6578650000", 1784
600 DATA "0000000D0A2A2A204520522052204F2052202A2A", 0777
610 DATA "0D0A240D0A0A496E74726F64757A636120656C20", 1424
620 DATA "6F726967696E616C204752595A4F5220656E206C", 1761
630 DATA "6120756E6964616420413A20792070756C736520", 1683
640 DATA "756E61207465636C612E2E2E2024000000000000", 1083

¿Alguna idea de que puede ser? Gracias.

[skywalky]

Pues según parece está fallando el checksum de una linea DATA así que comprueba la línea 580 ya que puede ser que el error esté ahí. Si nos dices en que Micromania está ese cargador quizá podamos ayudarte más.

[vreyes1981]

Buenas: el Micromanía en cuestión es un suplemento que se llama "Los 100 Mejores Juegos para PC"

De todas formas le echo ese vistazo en la línea 580 como tu bien dices...

[Crafterlock]

Una cosa quiero comentar respecto a los cargadores de la susodicha revista, la mayoría son obra de Javier Sánchez Fransesch (que en su momento comprobé que la mayoría funcionaban sin problemas), mas hay dos cargadores de Jesús Prez Sicilia (el del "Gryzor"y el del "Platoon") y ninguno de los dos funcionan.
¿Casualidad? No lo creo.

[vreyes1981]

Eso quiere decir que los  cargadores de Platoon y Gryzor no funcionan porque los códigos están mal de forma ex-profesa?

[Crafterlock]

Hombre, no diría tanto, pero que pueden tener algún error de transcripción, podría ser (como el nombre del creador de los cargadores, está claro que se llama "Pérez" y no "Prez").
Lamentablemente no tengo suficientes conocimientos para hallar una solución.
El del "Gryzor" no recuerdo haberlo visto en ningún otro lado, pero el del "Platoon" sí. Si lo encuentro los compararé, así al menos podremos saber si es un error de transcripción, o si es que el señor este no estaba por la labor...

[necromode]

En powerbasic de la época se puede tracear...
Doy una pista:
El cálculo del checksum de la línea 5 es 1963
El valor (suma) que debería dar es 1915
1963-1915 = 48dec = 30hex
Es probable que en la línea 5 se haya confundido un 8 por una B o similar.
He restado -30hex a todos los pares hex en esa línea individualmente (únicamente en los que el resultado es mayor a 0) y generado los cargadores .com correspondientes.
Probados todos, el único que no da error o fenónemos adversos (el cargador .com genera un ** ERROR **) es el B4 (correspondiente al último dígito hex de la línea).
Sustituido por 84. Ejecutado el cargador y cargado el juego, no tiene vidas infinitas...
He bajado ese número de la revista y aprecio, que donde pone 5EBE en el .bas del hilo, yo diría que en la revista se parece más a 5E8E, el cálculo del checksum es correcto (1915) pero da ** error ** el cargador resultante.
Vaya misterio!
------------------
Bueno muchachos y no tan muchachos. Ya tengo la solución. (El fallo de transcripción de la revista a texto estaba en el (B8 00 5E BE)). Debería ser (B8 00 5E 8E).
Este no es un cargador TSR (residente en memoria), se encarga de ejecutar el GRYZOR.EXE.
Pero existe un pequeño problema, en el dos box .conf se monta la unidad en C, y después se accede a la carpeta GRYZOR, pero el cargador ejecuta el GRYZOR.EXE desde la ruta a:\gryzor.exe
Hechas las modificaciones pertinentes, lo tengo operativo.
Quizá la mejor solución sería, cambiar el byte incorrecto y modificar el .BAS para que la ruta de ejecución sea .\GRYZOR.EXE en la línea 590 (modificando también el checksum) , así independientemente de la carpeta donde esté el ejecutable lo va a encontrar igual.
Por si queréis trastear he utilizado el Powerbasic PB35 para DOS y el IDA 7.7.
------------------
Bueno, me dejo de tonterías y vamos a la solución práctica.
Aquí el spoiler con el .BAS modificado para que funcione como debe:

Spoiler (click para mostrar/ocultar)

10 REM -----------------------------------------
20 REM Cargador Gryzor por Victor Reyes Morales
30 REM -----------------------------------------
40 REM
50 N$ = "CGRYZ": NB = 220: NL = NB / 20: DIM BYTE(NB): A=10: B=11: C=12: D=13: E=14: F=15
60 COLOR 6, 0, 0: CLS
70 LOCATE 13, 36: PRINT "ESPERE..."
80 CP = 0
90 FOR W1 = 1 TO NL
100 CHECKSUM = 0: Z = 1: READ L$, SUMA
110 FOR W2 = 1 TO 39 STEP 2
120 B1$ = MID$ (L$,Z,1): B2$ = MID$ (L$,Z+1,1): Z = Z + 2
130 A1 = ASC(B1$): A2 = ASC(B2$)
140 NIB1 = A1+48*(A1<58)+55*(A1>57): NIB2 = A2+48*(A2<58)+55*(A2>57)
150 BYTE(CP) = NIB1 * 16 + NIB2: CHECKSUM = CHECKSUM + BYTE(CP): CP = CP + 1
160 NEXT W2
170 IF CHECKSUM <> SUMA THEN CLS: LOCATE 12, 29: PRINT "ERROR EN LINEA DATA "; W1: LOCATE 22, 1: STOP
180 NEXT W1
190 LIN = 9: K = 255
200 CLS
210 LOCATE  1, 31: COLOR 7: PRINT "Cargador GRYZOR"
220 LOCATE  3, 23: COLOR 2: PRINT "(C) Victor Reyes Morales 2023": COLOR 6
230 LOCATE  9, 20: PRINT "Activar vidas infinitas Jugador 1 (s/n)?...... s"
240 LOCATE 11, 20: PRINT "Activar vidas infinitas Jugador 2 (s/n)?...... s"
250 LOCATE 13, 20: PRINT "Activar Tiempo Infinito (s/n)?................ s"
260 LOCATE 15, 20: PRINT "Activar Inmunidad ambos jugadores (s/n)?...... s"
270 LOCATE 17, 20: PRINT "Activar modo sin enemigos (s/n)?.............. s"
280 LOCATE 19, 20: PRINT "Unidad para salvar el cargador................. b"
290 GOSUB 490
300 IF X$ = "N" OR X$ = "n" THEN BYTE(54) = K: Y$ = X$
310 GOSUB 510: GOSUB 490
320 IF X$ = "N" OR X$ = "n" THEN BYTE(60) = K: Y$ = X$
330 GOSUB 510: GOSUB 490
340 IF X$ = "N" OR X$ = "n" THEN BYTE(66) = K: Y$ = X$
350 GOSUB 510: GOSUB 490
360 IF X$ = "N" OR X$ = "n" THEN BYTE(71) = K: Y$ = X$
370 GOSUB 510: GOSUB 490
380 IF X$ = "N" OR X$ = "n" THEN BYTE(76) = K: Y$ = X$
390 GOSUB 510: GOSUB 490
400 IF X$ = CHR$ (13) THEN X$ = "b"
410 Y$ = X$: U$ = X$: GOSUB 510
420 LOCATE 22, 26: COLOR 0,3: PRINT " Pulsa <INTRO> si es correcto ": COLOR 6, 0: X$ = INPUT$(1): IF X$ <> CHR$(13) THEN RUN
430 FOR F = 0 TO NB-1: COD$ = COD$ + CHR$ (BYTE(F)): NEXT
440 OPEN "O", #1, U$+":"+N$+".COM", NB
450 PRINT #1, COD$
460 CLOSE
470 CLS
480 SYSTEM
490 Y$ = "s": LOCATE LIN, 65: COLOR 4: PRINT CHR$(17): COLOR 6: X$ = INPUT$(1)
500 RETURN
510 LOCATE LIN, 63: PRINT Y$;"  ": LIN = LIN + 2
520 RETURN
530 REM
540 DATA "0E588ED88EC0B4098D168F01CD21B408CD218D16", 2117
550 DATA "6901C70677016529C706790165298D1E7701B44B", 1588
560 DATA "B003CD21722FB855298ED8C70639439090C7066B", 2175
570 DATA "449090C6060004C3C606F632EBC606E642C38EC0", 2523
580 DATA "B8005E8ED0BC8000EA1000A22F0E1F8D167B01B4", 1915
590 DATA "09CD21CD202E5C6772797A6F722E657865000000", 1675
600 DATA "0000000D0A2A2A204520522052204F2052202A2A", 0777
610 DATA "0D0A240D0A0A496E74726F64757A636120656C20", 1424
620 DATA "6F726967696E616C204752595A4F5220656E206C", 1761
630 DATA "6120756E6964616420413A20792070756C736520", 1683
640 DATA "756E61207465636C612E2E2E2024000000000000", 1083

[kurt]

Ostras, pedazo de trabajo de investigación y de solución te has marcado. Que crack!!!

Gracias

[vreyes1981]

(...) Bueno muchachos y no tan muchachos. Ya tengo la solución. (El fallo de transcripción de la revista a texto estaba en el (B8 00 5E BE)). Debería ser (B8 00 5E 8E).

 

Edito:

Confirmado que se ejecuta correctamente:

¡Muchas gracias @necromode por tu ardua investigación!

[necromode]

Aquí en el spoiler os dejo el cargador del PLATOON revisado y corregido extraído de la misma revista:
Tener en cuenta que el ejecutable que busca el cargador es .\o.exe

Spoiler (click para mostrar/ocultar)

10 REM -------------------------------------------
20 REM Cargador de PLATOON por Jesús Prez Sicilia
30 REM -------------------------------------------
40 REM
50 N$ = "CPLAT": NB = 200: NL = NB / 20: DIM BYTE(NB): A=10: B=11: C=12: D=13: E=14: F=15
60 COLOR 6, 0, 0: CLS
70 LOCATE 13, 36: PRINT "ESPERE ..."
80 CP = 0
90 FOR W1 = 1 TO NL
100 CHECKSUM = 0: Z = 1: READ L$, SUMA
110 FOR W2 = 1 TO 39 STEP 2
120 B1$ = MID$ (L$,Z,1): B2$ = MID$ (L$,Z+1,1): Z = Z + 2
130 A1 = ASC(B1$): A2 = ASC(B2$)
140 NIB1 = A1+48*(A1<58)+55*(A1>57): NIB2 = A2+48*(A2<58)+55*(A2>57)
150 BYTE(CP) = NIB1 *16 + NIB2: CHECKSUM = CHECKSUM + BYTE(CP): CP = CP + 1
160 NEXT W2
170 IF CHECKSUM <> SUMA THEN CLS: LOCATE 12, 29: PRINT "ERROR EN LINEA DATA "; W1: LOCATE 22, 1: STOP
180 NEXT W1
190 LIN = 9: K = 255
200 LOCATE 1, 30: COLOR 7: PRINT "Cargador   P L A T O O N"
210 LOCATE 3, 23: COLOR 2: PRINT "(C) Jesús Prez Sicilia  Granada 1989": COLOR 6
220 LOCATE  9, 25: PRINT "¿ Vidas infinitas (s/n) ? ...... s"
230 LOCATE 11, 25: PRINT "¿ Moral infinita (s/n) ? ....... s"
240 LOCATE 13, 25: PRINT "¿ Disparos infinitos (s/n) ? ... s"
250 LOCATE 15, 25: PRINT "¿ Inmune a trampas (s/n) ? ..... s"
260 LOCATE 17, 25: PRINT "¿ Juego sin enemigos (s/n) ? ... s"
270 LOCATE 19, 25: PRINT "Unidad para salvar el cargador . b"
280 GOSUB 480
290 IF X$ = "N" OR X$ = "n" THEN BYTE(57) = K: BYTE(61) = K: Y$ = "n"
300 GOSUB 500: GOSUB 480
310 IF X$ = "N" OR X$ = "n" THEN BYTE(65) = K: BYTE(69) = K: Y$ = "n"
320 GOSUB 500: GOSUB 480
330 IF X$ = "N" OR X$ = "n" THEN BYTE(73) = K: Y$ = "n"
340 GOSUB 500: GOSUB 480
350 IF X$ = "N" OR X$ = "n" THEN BYTE(77) = K: Y$ = "n"
360 GOSUB 500: GOSUB 480
370 IF X$ = "N" OR X$ = "n" THEN BYTE(83) = K: BYTE(87) = K: Y$ = "n"
380 GOSUB 500: GOSUB 480
390 IF X$ = CHR$ (13) THEN X$ = "b"
400 Y$ = X$: U$ = X$: GOSUB 500
410 LOCATE 22, 26: COLOR 0,3: PRINT " Pulsa  <Intro>  si es correcto ": COLOR 6, 0: X$ = INPUT$(1): IF X$ <> CHR$(13) THEN RUN
420 FOR F = 0 TO NB-1: COD$ = COD$ + CHR$ (BYTE(F)): NEXT
430 OPEN "O", #1, U$+":"+N$+".COM", NB
440 PRINT #1, COD$
450 CLOSE
460 CLS
470 SYSTEM
480 Y$ = "s": LOCATE LIN, 60: COLOR 4: PRINT CHR$(17): COLOR 6: X$ = INPUT$(1)
490 RETURN
500 LOCATE LIN, 58: PRINT Y$;"  ": LIN = LIN + 2
510 RETURN
520 REM
530 DATA "0E58892E90018C169401892692018ED88EC08D16", 1918 : REM  /  1 /
540 DATA "9601C7069F01EA1CC706A101EA1C8D1E9F01B44B", 1993 : REM  /  2 /
550 DATA "B003CD21724AB81B228ED8BB9090891EC93E891E", 2280 : REM  /  3 /
560 DATA "CB3E891EED3E883EEC3E891E643DC7069039C300", 2156 : REM  /  4 /
570 DATA "891E6F18891E7118B8DA1C8ED88EC0B8DC218ED0", 2515 : REM  /  5 /
580 DATA "BCE80329C08BD88BD38BEA8BF58BFEEA00001B22", 2806 : REM  /  6 /
590 DATA "8D16A301B409CD210E1F8B2E90018B2692018E16", 1617 : REM  /  7 /
600 DATA "9401CD200000000000002E5C6F2E657865000000", 1003 : REM  /  8 /
610 DATA "0000002A2A2A204520522052204F2052202A2A2A", 838  : REM  /  9 /
620 DATA "0D0A240000000000000000000000000000000000", 59   : REM  / 10 /

[Crafterlock]

Llevaba más de treinta años frustrado con el maldito cargador del "Platoon". No te puedes imaginar lo agradecido que estoy por este favor que nos has hecho.
¡Mil gracias @necromode!

[necromode]

30 años, ¡mae mía!

En el spoiler, a modo de preservación (igual a la revista) , el cargador del Gryzor corregido.

Spoiler (click para mostrar/ocultar)

10 REM ---------------------------------------
20 REM Cargador GRYZOR por Jesús Prez Sicilia
30 REM ---------------------------------------
40 REM
50 N$ = "CGRYZ": NB = 220: NL = NB / 20: DIM BYTE(NB): A=10: B=11: C=12: D=13: E=14: F=15
60 COLOR 6, 0, 0: CLS
70 LOCATE 13, 36: PRINT "ESPERE ..."
80 CP = 0
90 FOR W1 = 1 TO NL
100 CHECKSUM = 0: Z = 1: READ L$, SUMA
110 FOR W2 = 1 TO 39 STEP 2
120 B1$ = MID$ (L$,Z,1): B2$ = MID$ (L$,Z+1,1): Z = Z + 2
130 A1 = ASC(B1$): A2 = ASC(B2$)
140 NIB1 = A1+48*(A1<58)+55*(A1>57): NIB2 = A2+48*(A2<58)+55*(A2>57)
150 BYTE(CP) = NIB1 * 16 + NIB2: CHECKSUM = CHECKSUM + BYTE(CP): CP = CP + 1
160 NEXT W2
170 IF CHECKSUM <> SUMA THEN CLS: LOCATE 12, 29: PRINT "ERROR EN LINEA DATA "; W1: LOCATE 22, 1: STOP
180 NEXT W1
190 LIN = 9: K = 255
200 CLS
210 LOCATE 1, 31: COLOR 7: PRINT "Cargador   G R Y Z O R"
220 LOCATE 3, 23: COLOR 2: PRINT "(C) Jesús Prez Sicilia  Granada 1989": COLOR 6
230 LOCATE  9, 20: PRINT "¿ Vidas infinitas Jugador 1 (s/n) ? ...... s"
240 LOCATE 11, 20: PRINT "¿ Vidas infinitas Jugador 2 (s/n) ? ...... s"
250 LOCATE 13, 20: PRINT "¿ Tiempo infinito (s/n) ? ................ s"
260 LOCATE 15, 20: PRINT "¿ Inmunidad ambos jugadores (s/n) ? ...... s"
270 LOCATE 17, 20: PRINT "¿ Juego sin indígenas (s/n) ? ............ s"
280 LOCATE 19, 20: PRINT "Unidad para salvar el cargador ........... b"
290 GOSUB 490
300 IF X$ = "N" OR X$ = "n" THEN BYTE(54) = K: Y$ = X$
310 GOSUB 510: GOSUB 490
320 IF X$ = "N" OR X$ = "n" THEN BYTE(60) = K: Y$ = X$
330 GOSUB 510: GOSUB 490
340 IF X$ = "N" OR X$ = "n" THEN BYTE(66) = K: Y$ = X$
350 GOSUB 510: GOSUB 490
360 IF X$ = "N" OR X$ = "n" THEN BYTE(71) = K: Y$ = X$
370 GOSUB 510: GOSUB 490
380 IF X$ = "N" OR X$ = "n" THEN BYTE(76) = K: Y$ = X$
390 GOSUB 510: GOSUB 490
400 IF X$ = CHR$ (13) THEN X$ = "b"
410 Y$ = X$: U$ = X$: GOSUB 510
420 LOCATE 22, 26: COLOR 0,3: PRINT " Pulsa  <INTRO>  si es correcto ": COLOR 6, 0: X$ = INPUT$(1): IF X$ <> CHR$(13) THEN RUN
430 FOR F = 0 TO NB-1: COD$ = COD$ + CHR$ (BYTE(F)): NEXT
440 OPEN "O", #1, U$+":"+N$+".COM", NB
450 PRINT #1, COD$
460 CLOSE
470 CLS
480 SYSTEM
490 Y$ = "s": LOCATE LIN, 65: COLOR 4: PRINT CHR$(17): COLOR 6: X$ = INPUT$(1)
500 RETURN
510 LOCATE LIN, 63: PRINT Y$;"  ": LIN = LIN + 2
520 RETURN
530 REM
540 DATA "0E588ED88EC0B4098D168F01CD21B408CD218D16", 2117
550 DATA "6901C70677016529C706790165298D1E7701B44B", 1588
560 DATA "B003CD21722FB855298ED8C70639439090C7066B", 2175
570 DATA "449090C6060004C3C606F632EBC606E642C38EC0", 2523
580 DATA "B8005E8ED0BC8000EA1000A22F0E1F8D167B01B4", 1915
590 DATA "09CD21CD202E5C6772797A6F722E657865000000", 1675
600 DATA "0000000D0A2A2A204520522052204F2052202A2A", 0777
610 DATA "0D0A240D0A0A496E74726F64757A636120656C20", 1424
620 DATA "6F726967696E616C204752595A4F5220656E206C", 1761
630 DATA "6120756E6964616420413A20792070756C736520", 1683
640 DATA "756E61207465636C612E2E2E2024000000000000", 1083

[SkaZZ]

Oh, GW-BASIC, ojalá lo hubiera visto antes. Te lo voy a pasar a QuickBasic, pues el compilador v4.5 se puede encontrar en la red o puedes también usar QB64, para que se puede compilar.

NO GOTO, NO CRY!

[Crafterlock]

Yo uso el QuickBasic 1.1, con el DosBox claro. Es el que he usado toda la vida, y últimamente me muevo más por entorno Dos emulado que por Windows... 

[Crafterlock]

Veamos @necromode te cuento.

No me funciona el cargador del "Platoon", y lo que no entiendo es, como indicas, que el ejecutable que busca es el o.exe, cuando no existe en el juego ningún ejecutable con ese nombre.
Entonces, si se arranca el cargador da error, y si -por probar- se le cambia el nombre al ejecutable real del juego (platoon.exe) por o.exe, al ejecutar el cargador, se cuelga.

¿Hay alguna solución, o realmente no existe un cargador que pueda con este juego?